Linking Report Pages

How to:

With a StyleSheet, you can insert one or more navigational hyperlinks in a multi-page HTML report. This feature makes it easy for you to link consecutive report pages together without creating individual hyperlinks for each page.

You can define any report component as a hyperlink.

Syntax: How to Link Report Pages

Use the following syntax in an HTML report 

URL=#_destination, $

where:

destination
Is one of the following:

#_next goes to the top of the next report page.

#_previous goes to the top of the previous report page.

#_top goes to the top of the current report page.

#_start goes to the first page of the report.

#_end goes to the last page of the report.

Note: In order to use these destinations in a self service applications, the following command must be issued at the beginning of the FOCEXEC: 

SET BASEURL=''

Example: Linking Report Pages Through Images in a Heading

This request displays two images in the page heading of a long report. It creates a link between BULLET.GIF and the next page of the report, and GOBACK.GIF and the previous page of the report. 

TABLE FILE GGORDER
ON TABLE SUBHEAD
"COFFEE GRINDER SALES BY STORE"
" "
HEADING
"Next page or previous page."
PRINT QUANTITY AS 'Ordered Units' BY STORE_CODE BY PRODUCT NOPRINT
BY ORDER_NUMBER
WHERE PRODUCT EQ 'Coffee Grinder'
ON STORE_CODE PAGE-BREAK
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=TABHEADING, STYLE=BOLD,$ 
TYPE=HEADING, IMAGE=/IBI_APPS/IBI_HTML/GGDEMO/BULLET, URL=#_next, 
IMAGEALIGN=LEFT,$
TYPE=HEADING, IMAGE=/IBI_APPs/IBI_HTML/GGDEMO/GOBACK, URL=#_previous, 
IMAGEALIGN=RIGHT,$ 
ENDSTYLE
END

The images display in each page heading.

Click the image on the left of page 1 to display page 2.

Click the "go back" image on page 2 to redisplay page 1.

For details on including and positioning images in a report, see Laying Out the Report Page.

Note that if this procedure is part of a self-service application, the following command must be issued at the start of the procedure: 

SET BASEURL = ''

Example: Linking Pages Through Page Number and Heading Elements

This request creates hyperlinks from the page number to the next page in the report, and from the text of the page heading, which appears at the top of every report page, back to the previous page or to the first page. 

TABLE FILE GGORDER
ON TABLE SUBHEAD
"COFFEE GRINDER SALES BY STORE"
" "
HEADING
"return to previous page"
"return to beginning"
PRINT QUANTITY AS 'Ordered Units' BY STORE_CODE BY PRODUCT NOPRINT
BY ORDER_NUMBER
WHERE PRODUCT EQ 'Coffee Grinder'
ON STORE_CODE PAGE-BREAK
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=TABHEADING, STYLE=BOLD,$
TYPE=PAGENUM, URL=#_next, $ 
TYPE=HEADING, LINE=1, URL=#_previous, $
TYPE=HEADING, LINE=2, URL=#_start, $
ENDSTYLE
END

The first page looks as follows:

Click the page number three times to move to PAGE 4.

Click previous page to return to PAGE 3. Click return to beginning to go directly to PAGE 1.

Note that if this procedure is part of a self-service application, the following command must be issued at the start of the procedure: 

SET BASEURL = ''