ArrowObject.HeadSize

SVB Example

Adding and customizing an arrow on a graph:

Option Base 1
Sub Main
    'this example works best when ran on exp.sta included in the Statistica examples
    'directory
    Dim newanalysis As Analysis
    Set newanalysis = Analysis (sc2dScatterplots, ActiveDataSet)
    With newanalysis.Dialog
        .Variables = ""
        .GraphType = scRegularPlot
        .FitType = scFitLinear
        .Ellipse = scEllipseOff
        .EllipseCoefficient = 0.950000
        .RegressionBands = scRegressionBandOff
        .RegressionBandsLevel = 0.950000
        .DisplayCorrelationAndP = False
        .DisplayRegressionEquation = False
        .DisplayRSquare = False
    End With
    Dim OutGraph As Graph
    'set graph variable OutGraph to the first graph created by the analysis
    Set OutGraph = newanalysis.Dialog.Graphs(1)
    Dim ArrowObj As ArrowObject
    'add a new dynamic arrow to the graph beginning at 2,3 and ending at 6,8
    Set ArrowObj = OutGraph.ExtraObjects.AddDynamicArrow(2,3,6,8)
    'set the head angle of the arrow object to 60, the arrow head will appear
    'more flattened
    ArrowObj.HeadAngle = 60
    Dim HSize As Size
    'set the size variable HSize to the arrow objects head size
    Set HSize = ArrowObj.HeadSize
    'set the headsize value to 20
    HSize.Value = 20
    Dim Lne As Line
    'set the line variable lne to the arrow object line
    Set Lne = ArrowObj.Line
    'change the foreground color of the line to red 
    Lne.ForegroundColor = RGB(255,0,0)
    Dim PointCords As PointCoordinates
    'set the PointCorrdinates variable pointcords to the arrow object tail
    Set PointCords = ArrowObj.Tail
    'set the x value for the arrow tail to 8
    PointCords.X = 8
    'display the output graph
    OutGraph.Visible = True
End Sub